Keyboard shortcuts

Press ← or → to navigate between chapters

Press S or / to search in the book

Press ? to show this help

Press Esc to hide this help

Valores, tipos e variáveis

Variáveis guardam valores que podem mudar; constantes travam o nome naquele valor inicial. Você pode anotar o tipo explicitamente com dois-pontos ou deixar o compilador inferir para você.

var, const e inferência

Use var quando o valor vai mudar ao longo do programa, e const quando quiser garantir que aquele nome não seja reatribuído. Para deixar o contrato bem claro (especialmente em bibliotecas e funções), anote o tipo logo após o nome com dois-pontos.

var contador: inteiro = 0
var titulo = "CGD"
const limite: inteiro = 10

Tipos disponíveis e valores iniciais padrão

Se você declarar uma variável tipada sem valor inicial, tipos primitivos e coleções já nascem prontos para uso — já objetos, funções e tuplas começam como nulo para não rodar código escondido.

RecursoComo funciona
numero / númeroAceita inteiro e real; começa em 0.
inteiro / longoInteiro de 64 bits com sinal. Se estourar o limite (overflow), lança erro tratável.
real / decimalNúmero decimal de ponto flutuante (64 bits); começa em 0.0.
logico / booleano / binarioverdadeiro ou falso; começa em falso.
textoTexto UTF-8 imutável; começa vazio (""). Índices contam caracteres Unicode.
T[]Vetor tipado (ex.: inteiro[], texto[]); começa como um vetor vazio novo.
dicionario / dicionárioMapa de chave e valor; começa como um dicionário vazio novo.
Promessa e TarefaTipos nativos do CGD para funções assincrona e rotinas paralelas.
qualquer, classe, interface, funcao, tuplaComeçam como nulo quando declarados sem valor inicial.

Literais numéricos e comentários

Inteiros podem ser escritos em decimal, hexadecimal (0x / 0X), binário (0b / 0B) ou octal (0o / 0O), com separadores opcionais _ entre dígitos. Números reais aceitam separadores _, notação científica decimal (e / E) e ponto flutuante hexadecimal IEEE-754 (0x...p...). Comentários podem ser de linha (//) ou de bloco (/* ... */).

/* Literais inteiros e reais com separadores e bases */
const mascara: inteiro = 0xFFFF_FFFF
const flags: inteiro = 0b1111_0000
const permissao: inteiro = 0o755
const populacao: inteiro = 1_000_000
const pequeno: real = 1.25e-8
const piAprox: real = 3_141.592_653
const hexReal: real = 0x1.fp+3

Experimente: 01_tipos

// Declaração, valores primitivos e tipo de em execução.
var vazio: qualquer
const ativo: logico = verdadeiro
var idade: inteiro = 20
var medida: real = 2.5
escreva(vazio, ativo)
escreva(tipo de idade, " ", tipo de medida, " ", tipo de "olá", " ", tipo de ativo)

Ver exemplo completo e contrato de teste no GitHub

Experimente: 03_atribuicoes

var a: numero, b: numero = 1, 2
a, b = b, a // Os valores da direita são avaliados antes das escritas.
var contador: numero = 2
contador += 5
escreva(a, b, contador)
var destino: numero = 0
escreva(destino = 5)

Ver exemplo completo e contrato de teste no GitHub

Experimente: 25_escopos

var x: numero = 1
se verdadeiro {
    var x: numero = 2;
    escreva(x)
}

escreva(x)
funcao criar(): qualquer {
    retorna auxiliar
    funcao auxiliar(x: qualquer): qualquer {
        retorna x * 2
    }
}

escreva(criar()(4))

Ver exemplo completo e contrato de teste no GitHub

const impede reatribuir a variável, mas se ela guardar um vetor ou dicionário, você ainda pode alterar os itens lá dentro. Inteiros têm 64 bits verificados e reais usam ponto flutuante de 64 bits (não existe BigInt).