Keyboard shortcuts

Press ← or → to navigate between chapters

Press S or / to search in the book

Press ? to show this help

Press Esc to hide this help

Membros estáticos (campos e métodos)

Membros marcados com estatico pertencem à classe inteira, não a um objeto específico. São ótimos para contadores compartilhados, constantes e fábricas de objetos.

Declarando campos e métodos estáticos

Use estatico (ou estático) tanto em campos quanto em métodos. Eles respeitam publico, protegido e privado e podem ser herdados normalmente.

classe Fabrica {
    estatico criados: inteiro = 0

    estatico proximoId(): inteiro {
        Fabrica.criados++
        retorna Fabrica.criados
    }
}
escreva(Fabrica.proximoId())

Experimente: estaticos

classe Calculadora {
    estatico dobro(valor: inteiro): inteiro {
        retorna valor * 2
    }
}

classe Avancada herda Calculadora {
}

escreva(Calculadora.dobro(3))
escreva(Avancada.dobro(4))
var calculadora: Calculadora = Calculadora()
escreva(calculadora.dobro(5))

Ver exemplo completo e contrato de teste no GitHub

Experimente: 43_estaticos_mescla

funcao de decorador triplicar(original: funcao): funcao {
    retorna funcao(alvo: qualquer, x: inteiro): inteiro {
        retorna x * 3
    }
}

classe Etiquetavel {
    prefixo: texto = "Etiqueta:"

    rotulo(nome: texto): texto {
        retorna isto.prefixo + nome
    }
}

classe Registro mescla Etiquetavel {
    estatico criados: inteiro = 0
    nome: texto

    construtor(nome: texto) {
        isto.nome = nome
        Registro.criados = Registro.criados + 1
    }

    @triplicar
    escalar(x: inteiro): inteiro {
        retorna x
    }
}

const a: Registro = Registro("Ana")
const b: Registro = Registro("Bia")
escreva(Registro.criados)
escreva(a.rotulo(a.nome))
escreva(b.eInstanciaDe(Etiquetavel))
escreva(a.escalar(10))

Ver exemplo completo e contrato de teste no GitHub

Métodos estáticos não recebem isto. Campos estáticos suportam anotações de tipo, defaults, visibilidade e validação de escrita — e são bloqueados dentro de rotinas paralelas (E3402) para manter o isolamento entre threads.